!--------( AMAG : <amag> inversion          )--------
  implicit none
  integer,parameter :: KVER = 2018
  integer :: lwkdir, lrtrim
  real,allocatable :: f(:,:), r(:,:), q(:,:), g(:)
  real,allocatable :: s(:,:), p(:,:), v(:,:)
  real :: coef(3)
  character(80) :: wdr, flog, fnam1, fnam2, fnam3, fnam4, buf
  character(72) :: out;  character(20) :: sdtm
  character(8) :: area, area1, salt;  character(1) :: yn
  integer :: ldr, n, i, j, k, ilp, klp, nlp, nloop, ip, jp, nver, IER
  integer :: nc, ncc, iorg, korg, ispa, ispb
  integer :: nc1, ncc1, iorg1, korg1, ispa1, ispb1
  integer :: ixl, iyl, mszx, mszy, mx, my, nhx, nhy, nfx, nfy
  integer :: ixs, iys, mszxm, mszym, ixs1, iys1, mszxm1, mszym1
  integer :: ixl1, iyl1, mszx1, mszy1, mxm1, mym1, mx1, my1
  integer :: mxm, mym, nnfw, kout
  real :: x, y, hw, xl, yl, anul, dmy, ds, ss, dv, vm
  real :: pvv, pvvp, a, pqq, af, bf, cf, cmx, cmy, ft, vnul
  real :: alt, alt1, c, xs, ys

  call premsg('AMAG : <amag> inversion')
  call opnpin()
  ldr = lwkdir(50,wdr) + 1
  flog = wdr;  fnam1 = wdr;  fnam2 = wdr;  fnam3 = wdr;  fnam4 = wdr
  call gparma('Enter LOG filename ==> ', 81-ldr, flog(ldr:80))
  call gparma('Enter Mag.Anomaly data filename   ==> ', 81-ldr, fnam1(ldr:80))
  open(12,file=fnam1,status='old')
  do
    read(12,'(a)') buf
    if (buf(1:1) /= '#') exit
  enddo
  if (buf(13:16) == '    ') then        !-- v2005
    read(buf,'(a8,i4,4x,4i8)') area, ncc, iorg, korg, ispa, ispb
    if ((ncc<0) .or. (ncc>=400)) call abendm('invalid coord.no.')
    nc = ncc
    if (ncc < 200) then
      nc = ncc; ncc = nc + 800
    else
      ncc = ncc - 200; nc = ncc
    endif
  else                                  !-- v2018
    read(buf,'(a8,4x,i4,4i8)') area, ncc, iorg, korg, ispa, ispb
    nc = ncc
    if ((ncc >= 800) .and. (ncc < 1000)) nc = ncc - 800
  endif
  if ((nc >= 1) .and. (nc <= 62)) then
    iorg = 0;  ispa = 0;  ispb = 0
    korg = (nc-30)*360 - 180
    if (nc > 60) korg = 0
    if (nc == 61) iorg = +5400
    if (nc == 62) iorg = -5400
  endif
  read(12,'(a)') buf
  read(buf,*) ixs, iys, mszx, mszy, mx, my, vnul, alt

  if ((mx <= 0) .or. (my <= 0)) call abendm('illegal array size')
  allocate(f(mx,my));  allocate(r(mx,my));  allocate(q(mx,my))

  read(12,*) ((f(i,j),i=1,mx),j=1,my)
  close(12)
  call prompt('  Remove Linear trend ?  ')
  call gparma('  "y" (Yes) or "n" (No) ==> ', 1, yn)
  if ((yn /= 'y') .and. (yn /= 'n')) call abendm('invalid parameter')

  call gparma('Enter COEF matrix data filename   ==> ', 81-ldr, fnam2(ldr:80))
  open(20,file=fnam2,form='unformatted',status='old')
  read(20) area1, nver, ncc1, iorg1,korg1, ispa1,ispb1,   &
          ixs1, iys1, mszx1, mszy1, mx1, my1, alt1,   &
          ixl,  iyl,  mszxm, mszym, mxm, mym, nhx, nhy
  if (nver /= KVER) call abendm('Version mismatch')
  if ((area1 /= area) .or. (ncc1 /= ncc) .or. (iorg1 /= iorg)   &
      .or. (korg1 /= korg) .or. (ispa1 /= ispa) .or. (ispb1 /= ispb))   &
    call abendm('Header inconsistent')
  if ((ixs1 /= ixs) .or. (iys1 /= iys) .or. (mszx1 /= mszx)   &
      .or. (mszy1 /= mszy) .or. (mx1 /= mx) .or. (my1 /= my))   &
    call abendm('Header inconsistent')
  if (alt < 0.) alt = alt1
  write(salt,'(1x,f7.0)') alt
  if (alt == 0.) salt = '    var.'
  if (alt < 0.) salt = '   undef'
  xs = float(ixs)/1000.;  ys = float(iys)/1000.
  xl = float(ixl)/1000.;  yl = float(iyl)/1000.
  write(out,'(a12,a8,6x,a6,i4,4x,4i8)')   &
    '--- Area :  ', area, 'Coord.', ncc, iorg,korg, ispa,ispb
  call premsg(out)
  write(out,'(a14,2a10,2x,2a8,2a6,a8)')   &
    '---   (mesh)  ', 'xs', 'ys', 'msz-x', 'msz-y', 'mx', 'my', 'alt '
  call premsg(out)
  write(out,'(a16,2f10.2,2i8,2i6,a8)')   &
    '--- mag. obs.   ', xs, ys, mszx, mszy, mx, my, salt
  call premsg(out)
  write(out,'(a16,2f10.2,2i8,2i6,a8)')   &
    '--- source model', xl,yl, mszxm,mszym, mxm,mym, '    --- '
  call premsg(out)
  hw = float(mszx*nhx) / 1000.
  nfx = nhx + 1 + nhx;  nfy = nhy + 1 + nhy;  nnfw = nfx * nfy

  allocate(s(mxm,mym)); allocate(p(mxm,mym)); allocate(v(mxm,mym))
  allocate(g(nnfw))

  call gparma('Enter AMAG model in/out filename  ==> ', 81-ldr, fnam3(ldr:80))
  open(21,file=fnam3,status='old')
  do
    read(21,'(a)') buf
    if (buf(1:1) /= '#') exit
  enddo
  if (buf(13:16) == '    ') then        !-- v2005
    read(buf,'(a8,i4,4x,4i8)') area1, ncc1, iorg1,korg1, ispa1,ispb1
    if ((ncc1<0) .or. (ncc1>=400)) call abendm('invalid coord.no.')
    nc1 = ncc1
    if (ncc1 < 200) then
      nc1 = ncc1; ncc1 = nc1 + 800
    else
      ncc1 = ncc1 - 200; nc1 = ncc1
    endif
  else                                  !-- v2018
    read(buf,'(a8,4x,i4,4i8)') area1, ncc1, iorg1,korg1, ispa1,ispb1
    nc1 = ncc1
    if ((ncc1 >= 800) .and. (ncc1 < 1000)) nc1 = ncc1 - 800
  endif
  if ((nc1 >= 1) .and. (nc1 <= 62)) then
    iorg1 = 0;  ispa1 = 0;  ispb1 = 0
    korg1 = (nc1-30)*360 - 180
    if (nc1 > 60) korg1 = 0
    if (nc1 == 61) iorg1 = +5400
    if (nc1 == 62) iorg1 = -5400
  endif
  read(21,*) ixl1, iyl1, mszxm1, mszym1, mxm1, mym1, anul, dmy, klp
  if ((area1 /= area) .or. (ncc1 /= ncc) .or. (iorg1 /= iorg)   &
      .or. (korg1 /= korg) .or. (ispa1 /= ispa) .or. (ispb1 /= ispb))   &
    call abendm('Header inconsistent')
  if ((ixl1 /= ixl) .or. (iyl1 /= iyl) .or. (mszxm1 /= mszxm)   &
      .or. (mszym1 /= mszym) .or. (mxm1 /= mxm) .or. (mym1 /= mym))   &
    call abendm('Header inconsistent')
  read(21,*) ((s(i,j),i=1,mxm),j=1,mym)
  rewind(21)

  call premsg('Enter Auxiliary(2) output filename')
  call gparma('     ( blank to suppress output ) ==> ', 81-ldr, fnam4(ldr:80))
  kout = 0
  if (fnam4(ldr:ldr) /= ' ') then
    open(8,file=fnam4,status='new')
    kout = 1
  endif
  call premsg('How many loops to excute ?')
  call gparmi('   (minus to restart from loop-0) ==> ', nloop)
  nlp = iabs(nloop)
  if (nloop < 0) then
    call gparmf(' Initial value of magnetiz. (in A/m) ==> ', vm)
  endif
  call clspin()
  call strdtm(sdtm)

  call dpcini('.... read COEF matrix (0) : ')
  do j=1,mym; do i=1,mxm
    read(20) ip, jp, k, k, (c,k=1,nnfw)
    if ((ip /= i) .or. (jp /= j)) call abendm('COEF file broken')
    p(i,j) = 0.
    call dpcent((j-1)*mxm+i, mxm*mym)
  enddo; enddo
  rewind(20)

  write(6,'(a)') '----------------------------------------'
  write(6,'(a)') 'AMAG : <amag> inversion'
  write(6,'(a,a)') ' Mag. Anom. infile   : ', fnam1(1:lrtrim(fnam1))
  write(6,'(a,a)') ' COEF matrix infile  : ', fnam2(1:lrtrim(fnam2))
  write(6,'(a,a)') ' AMAG model i/o file : ', fnam3(1:lrtrim(fnam3))
  if (kout == 1)   &
    write(6,'(a,a)') ' Aux(2) output file  : ', fnam4(1:lrtrim(fnam4))
  write(6,'(a12,a8,6x,a6,i4,4x,4i8)')   &
    'Areaname :  ', area, 'Coord.', ncc, iorg, korg, ispa, ispb
  write(6,'(4x,a)')   &
    '  (mesh)          xs        ys     msz-x   msz-y    mx    my    alt '
  write(6,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
    'mag. obs.   ', xs, ys, mszx, mszy, mx, my, salt
  write(6,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
    'source model', xl, yl, mszxm, mszym, mxm, mym, '    --- '
  write(6,'(a,f6.2,a,i4,a,i4,a)')   &
    ' Half width of calc.window :', hw, ' km (', nhx, ' *', nhy, '  mag.mesh)'
  write(6,'(a,i4)') ' Max. Loop count :', nloop
  if (nloop < 0) write(6,'(a,f6.2,a)')   &
    ' Starting from Initial magnetization :', vm, ' A/m'

  n = 0;  ss = 0.
  do j=1,my; do i=1,mx
    if (f(i,j) == vnul) cycle
    ss = ss + f(i,j);  n = n + 1
  enddo; enddo
  ft = ss / float(n);  ss = 0.
  do j=1,mym; do i=1,mxm;  ss = ss + s(i,j)*s(i,j);  enddo; enddo
  ds = sqrt(ss / float(mxm*mym))

  if (nloop < 0) then
    klp = 0;  ds = 0.
    do j=1,mym; do i=1,mxm;  s(i,j) = vm * 100.;  enddo; enddo
  endif

  if (yn == 'y') then
    cmx = float(mx+1) / 2.;  cmy = float(my+1) / 2.
    call sm2opn(1, 1)
    do j=1,my
      y = float(j) - cmy
      do i=1,mx
        x = float(i) - cmx
        if (f(i,j) /= vnul) call sm2ex(x, y, f(i,j)-ft)
      enddo
    enddo
    call sm2cls(coef, 3, 1)
    cf = coef(1) + ft;  af = coef(2);  bf = coef(3)
    write(6,'(a,f8.2,a,f7.3,a,f7.3,a)')   &
      ' Trend surface removed (nT):', cf, ' + (', af, ' * x) + (', bf, ' * y)'
    write(6,'(5x,a)')   &
      '( x/y : N/E coord. in mesh unit referred to the center of area )'
    do j=1,my
      y = float(j) - cmy
      do i=1,mx
        x = float(i) - cmx
        if (f(i,j) /= vnul) f(i,j) = f(i,j) - (af*x + bf*y + cf)
      enddo
    enddo
    if (kout == 1) then
      write(8,'(a8,4x,i4,4i8)') 'Obs-Trnd', ncc, iorg,korg, ispa,ispb
      write(8,'(2i12,4i6,1x,f7.1,1x,f7.0)')   &
        ixs,iys, mszx,mszy, mx,my, vnul, -1.
      do j=1,my
        write(8,'((f7.1,9(1x,f7.1)))') (f(i,j),i=1,mx)
      enddo
      write(6,'(a)') 'AUX2 <== Obs-Trnd : Trend-removed Observation'
    endif
  else
    af = 0.;  bf = 0.;  cf = 0.
    write(6,'(a)') ' without Trend surface removal'
  endif

  call conv1(g, nfx, nfy, s, mxm, mym, r, mx, my)
  n = 0;  ss = 0.
  do j=1,my; do i=1,mx
    if (f(i,j) == vnul) then
      r(i,j) = 0.
    else
      r(i,j) = f(i,j) - r(i,j);  ss = ss + r(i,j)*r(i,j);  n = n + 1
    endif
  enddo; enddo
  dv = sqrt(ss / float(n))
  write(6,'(a,i4,a,f9.3,a,f7.2)')   &
    ' loop', klp, '   rms.Step :', ds, '   rms.Residual :', dv
  open(9,status='scratch')
  write(9,*) klp, ds, dv

  pvv = 1.
  do ilp=1,nlp
    klp = klp + 1;  pvvp = pvv
    call conv2(g, nfx, nfy, r, mx, my, v, mxm, mym)
    pvv = 0.
    do j=1,mym; do i=1,mxm;  pvv = pvv + v(i,j)*v(i,j);  enddo; enddo
    a = pvv / pvvp
    do j=1,mym; do i=1,mxm;  p(i,j) = v(i,j) + a*p(i,j);  enddo; enddo
    call conv1(g, nfx, nfy, p, mxm, mym, q, mx, my)
    pqq = 0.
    do j=1,my; do i=1,mx;  pqq = pqq + q(i,j)*q(i,j);  enddo; enddo
    a = pvv / pqq;  ss = 0.
    do j=1,mym; do i=1,mxm
      s(i,j) = s(i,j) + a*p(i,j);  ss = ss + p(i,j)*p(i,j)
    enddo; enddo
    ds = a * sqrt(ss / float(mxm*mym))
    n = 0;  ss = 0.
    do j=1,my; do i=1,mx
      if (f(i,j) == vnul) cycle
      r(i,j) = r(i,j) - a*q(i,j);  ss = ss + r(i,j)*r(i,j);  n = n + 1
    enddo; enddo
    dv = sqrt(ss / float(n))
    write(6,'(a,i4,a,f9.3,a,f7.2)')   &
      ' loop', klp, '   rms.Step :', ds, '   rms.Residual :', dv
    write(9,*) klp, ds, dv
  enddo
  write(6,'(1x)')
  endfile(9)
  rewind(9)

  write(21,'(a8,4x,i4,4i8)') area, ncc, iorg,korg, ispa,ispb
  write(21,'(2i12,4i6,1x,f7.1,1x,f7.0,i6)')   &
    ixl, iyl, mszxm, mszym, mxm, mym, anul, -1., klp
  do j=1,mym
    do i=1,mxm
      if (s(i,j) < -9999.8) s(i,j) = -9999.8
      if (s(i,j) > +9999.8) s(i,j) = +9999.8
    enddo
    write(21,'((f7.1,9(1x,f7.1)))') (s(i,j),i=1,mxm)
  enddo
  close(21)
  if (kout == 1) then
    call conv1(g, nfx, nfy, s, mxm, mym, r, mx, my)
    do j=1,my
      y = float(j) - cmy
      do i=1,mx
        x = float(i) - cmx
        if (f(i,j) == vnul) then
          r(i,j) = vnul;  q(i,j) = vnul
        else
          q(i,j) = r(i,j) + (af*x + bf*y + cf);  f(i,j) = f(i,j) - r(i,j)
        endif
      enddo
    enddo
    write(8,'(a8,4x,i4,4i8)') 'SynthMdl', ncc, iorg,korg, ispa,ispb
    write(8,'(2i12,4i6,1x,f7.1,1x,f7.0)')   &
      ixs,iys, mszx,mszy, mx,my, vnul, -1.
    do j=1,my
      write(8,'((f7.1,9(1x,f7.1)))') (r(i,j),i=1,mx)
    enddo
    write(6,'(a)') 'AUX2 <== SynthMdl : Synthetic model anomaly '
    if (yn == 'y') then
      write(8,'(a8,4x,i4,4i8)') 'Mdl+Trnd', ncc, iorg,korg, ispa,ispb
      write(8,'(2i12,4i6,1x,f7.1,1x,f7.0)')   &
        ixs,iys, mszx,mszy, mx,my, vnul, -1.
      do j=1,my
        write(8,'((f7.1,9(1x,f7.1)))') (q(i,j),i=1,mx)
      enddo
      write(6,'(a)') 'AUX2 <== Mdl+Trnd : Trend-added Synth. model'
    endif
    write(8,'(a8,4x,i4,4i8)') 'Residual', ncc, iorg,korg, ispa,ispb
    write(8,'(2i12,4i6,1x,f7.1,1x,f7.0)')   &
      ixs,iys, mszx,mszy, mx,my, vnul, -1.
    do j=1,my
      write(8,'((f7.1,9(1x,f7.1)))') (f(i,j),i=1,mx)
    enddo
    write(6,'(a)') 'AUX2 <== Residual : Residual <(Obs.) - (Model)>'
    close(8)
  endif
  close(20)

  if (flog(ldr:ldr) /= ' ') then
    open(99,file=flog,access='append')
    write(99,'(//a)') 'AMAG : <amag> inversion'
    write(99,'(a,a)') ' Mag. Anom. infile   : ', fnam1(1:lrtrim(fnam1))
    write(99,'(a,a)') ' COEF matrix infile  : ', fnam2(1:lrtrim(fnam2))
    write(99,'(a,a)') ' AMAG model i/o file : ', fnam3(1:lrtrim(fnam3))
    if (kout == 1)   &
      write(99,'(a,a)') ' Aux(2) output file  : ', fnam4(1:lrtrim(fnam4))
    write(99,'(a,a,a)') '--------------- ', sdtm, '---------------'
    write(99,'(a12,a8,6x,a6,i4,4x,4i8)')   &
      'Areaname :  ', area, 'Coord.', ncc, iorg, korg, ispa, ispb
    write(99,'(4x,a)')   &
      '  (mesh)          xs        ys     msz-x   msz-y    mx    my    alt '
    write(99,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
      'mag. obs.   ', xs, ys, mszx, mszy, mx, my, salt
    write(99,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
      'source model', xl, yl, mszxm, mszym, mxm, mym, '    --- '
    write(99,'(a,f6.2,a,i4,a,i4,a)') ' Half width of calc.window :',   &
      hw, ' km (', nhx, ' *', nhy, '  mag.mesh)'
    write(99,'(a,i4)') ' Max. Loop count :', nloop
    if (nloop < 0) then
      write(99,'(a,f6.2,a)')   &
        ' Starting from Initial magnetization :', vm, ' A/m'
    endif
    if (yn == 'y') then
      write(99,'(a,f8.2,a,f7.3,a,f7.3,a)') ' Trend surface removed (nT):',   &
        cf, ' + (', af, ' * x) + (', bf, ' * y)'
      write(99,'(5x,a)')   &
        '( x/y : N/E coord. in mesh unit referred to the center of area )'
    else
      write(99,'(a)') ' without Trend surface removal'
    endif
    do
      read(9,*,iostat=IER) klp, ds, dv
      if (IER < 0) exit
      write(99,'(a,i4,a,f9.3,a,f7.2)')   &
        ' loop', klp, '   rms.Step :', ds, '   rms.Residual :', dv
    enddo
    call strdtm(sdtm)
    write(99,'(a,a,a)') '=============== ', sdtm, '==============='
    close(99)
  endif
  close(9)
  stop
  end
!---
  subroutine conv1(g, nfx, nfy, s, mxm, mym, r, mx, my)
  implicit none
  integer,intent(in) :: nfx, nfy, mxm, mym, mx, my
  real,intent(inout) :: g(nfx,nfy)
  real,intent(in) :: s(mxm,mym)
  real,intent(out) :: r(mx,my)
  character(8) :: area
  integer :: nhx, nhy, ip, jp, is, js, i, j, k
  integer :: kic, kjc, kis, kjs

  nhx = (nfx-1) / 2;  nhy = (nfy-1) / 2
  call dpcini('.... read COEF matrix (1) : ')
  read(20) area, (i,k=1,21)
  do jp=1,my; do ip=1,mx;  r(ip,jp) = 0.;  enddo; enddo
  do js=1,mym; do is=1,mxm
    read(20) k, k, kic, kjc, g
    kis = kic - nhx;  kjs = kjc - nhy
    do j=1,nfy
      jp = kjs + j;  if ((jp <= 0) .or. (jp > my)) cycle
      do i=1,nfx
        ip = kis + i;  if ((ip <= 0) .or. (ip > mx)) cycle
        r(ip,jp) = r(ip,jp) + g(i,j)*s(is,js)
      enddo
    enddo
    call dpcent((js-1)*mxm+is, mxm*mym)
  enddo; enddo
  rewind(20)
  return
  end subroutine
!---
  subroutine conv2(g, nfx, nfy, r, mx, my, s, mxm, mym)
  implicit none
  integer,intent(in) :: nfx, nfy, mx, my, mxm, mym
  real,intent(inout) :: g(nfx,nfy)
  real,intent(in) :: r(mx,my)
  real,intent(out) :: s(mxm,mym)
  character(8) :: area
  integer :: nhx, nhy, i, j, k, is, js, ip, jp, kic, kjc, kis, kjs
  real :: ss

  nhx = (nfx-1) / 2;  nhy = (nfy-1) / 2
  call dpcini('.... read COEF matrix (2) : ')
  read(20) area, (i,k=1,21)
  do js=1,mym; do is=1,mxm
    read(20) k, k, kic, kjc, g
    kis = kic - nhx;  kjs = kjc - nhy
    ss = 0.
    do j=1,nfy
      jp = kjs + j;  if ((jp <= 0) .or. (jp > my)) cycle
      do i=1,nfx
        ip = kis + i;  if ((ip <= 0) .or. (ip > mx)) cycle
        ss = ss + g(i,j)*r(ip,jp)
      enddo
    enddo
    s(is,js) = ss
    call dpcent((js-1)*mxm+is, mxm*mym)
  enddo; enddo
  rewind(20)
  return
  end subroutine