!--------( ADEQSC : <adeqs> inversion until converge )--------
  implicit none
  integer,parameter :: KVER = 2018
  integer :: lwkdir, lrtrim
  real,allocatable :: f(:), r(:), q(:), g(:)
  real,allocatable :: s(:,:), p(:,:), v(:,:), t(:,:)
  character(80) :: wdr, flog, fnam1, fnam2, fnam3, buf
  character(72) :: out;  character(20) :: sdtm
  character(8) :: area, area1
  integer :: ldr, n, i, j, k, klp, lp, nloop, ilp, kc, ic, jc, nver, IER
  integer :: ncc, iorg, korg, ispa, ispb
  integer :: nc1, ncc1, iorg1, korg1, ispa1, ispb1
  integer :: ixl, iyl, mszx, mszy, mx, my, nhx, nhy, nfx, nfy
  integer :: ixl1, iyl1, mszx1, mszy1, mxm1, mym1
  integer :: ndpt, mxm, mym, ixlm, iylm, nnfw
  real :: x, y, h, hw, vd, xl, yl, xlm, ylm, anul, tnul, dmy, ds, ss, dv
  real :: hwm, pvv, pvvp, a, pqq, dip, dec, phi, the, thrsh, rv

  call premsg('ADEQSC : <adeqs> inversion until converge')
  call opnpin()
  ldr = lwkdir(50,wdr) + 1
  flog = wdr;  fnam1 = wdr;  fnam2 = wdr;  fnam3 = wdr
  call gparma('Enter LOG filename ==> ', 81-ldr, flog(ldr:80))
  call gparma('Enter StdLIN data filename        ==> ', 81-ldr, fnam1(ldr:80))
  open(1,file=fnam1,status='old')
  ndpt = 0
  do
    read(1,'(a)',iostat=IER) buf
    if (IER < 0) exit
    if ((buf(1:1) == '&') .or. (buf(1:1) == '%') .or. (buf(1:1) == '#')) cycle
    ndpt = ndpt + 1
  enddo
  rewind(1); n = 0
  allocate(f(ndpt));  allocate(r(ndpt));  allocate(q(ndpt))
  do
    read(1,'(a)',iostat=IER) buf
    if (IER < 0) exit
    if ((buf(1:1) == '&') .or. (buf(1:1) == '%') .or. (buf(1:1) == '#')) cycle
    n = n + 1
    i = index(buf,'N');  if (i /= 0) buf(i:i) = ' '
    i = index(buf,'E');  if (i /= 0) buf(i:i) = ' '
    i = index(buf,'m');  if (i /= 0) buf(i:i) = ' '
    i = index(buf,'nT');  if (i /= 0) buf(i:i+1) = '  '
    read(buf,*) x, y, h, f(n)
  enddo
  close(1)

  call gparma('Enter CFUPS matrix data filename  ==> ', 81-ldr, fnam2(ldr:80))
  open(20,file=fnam2,form='unformatted',status='old')
  read(20) area, nver, ncc, iorg,korg, ispa,ispb,   &
         ixl, iyl, mszx, mszy, mx, my, nhx, nhy, hw, vd
  if (nver /= KVER) call abendm('Version mismatch')
  xl = float(ixl)/1000.;  yl = float(iyl)/1000.
  ixlm = ixl - mszx*nhx;  iylm = iyl - mszy*nhy
  xlm = float(ixlm)/1000.;  ylm = float(iylm)/1000.
  mxm = mx + nhx + nhx;  mym = my + nhy + nhy
  if ((mx <= 0) .or. (my <= 0)) call abendm('illegal array size')
  if ((nhx < 10) .or. (nhy < 10)) call abendm('truncation too short')
  nfx = nhx + 1 + nhx;  nfy = nhy + 1 + nhy;  nnfw = nfx * nfy

  allocate(s(mxm,mym)); allocate(p(mxm,mym))
  allocate(v(mxm,mym)); allocate(t(mxm,mym))
  allocate(g(nnfw))

  write(out,'(a12,a8,6x,a5,i4,4x,4i8)')   &
    '--- Area :  ', area, 'Coord.', ncc, iorg,korg, ispa,ispb
  call premsg(out)
  write(out,'(a14,2a10,2x,2a8,2a6,a8)')   &
    '---   (mesh)  ', 'xs', 'ys', 'msz-x', 'msz-y', 'mx', 'my', 'alt '
  call premsg(out)
  write(out,'(a16,2f10.2,2i8,2i6,a8)')   &
    '--- reduc. surf.', xl, yl,  mszx,mszy, mx, my, '    --- '
  call premsg(out)
  write(out,'(a16,2f10.2,2i8,2i6,a8)')   &
    '--- equiv.source', xlm,ylm, mszx,mszy, mxm,mym, '    var.'
  call premsg(out)

  call gparma('Enter ADEQS model in/out filename ==> ', 81-ldr, fnam3(ldr:80))
  open(21,file=fnam3,status='old')
  do
    read(21,'(a)') buf
    if (buf(1:1) /= '#') exit
  enddo
  if (buf(13:16) == '    ') then        !-- v2005
    read(buf,'(a8,i4,4x,4i8)') area1, ncc1, iorg1,korg1, ispa1,ispb1
    if ((ncc1<0) .or. (ncc1>=400)) call abendm('invalid coord.no.')
    nc1 = ncc1
    if (ncc1 < 200) then
      nc1 = ncc1; ncc1 = nc1 + 800
    else
      ncc1 = ncc1 - 200; nc1 = ncc1
    endif
  else                                  !-- v2018
    read(buf,'(a8,4x,i4,4i8)') area1, ncc1, iorg1,korg1, ispa1,ispb1
    nc1 = ncc1
    if ((ncc1 >= 800) .and. (ncc1 < 1000)) nc1 = ncc1 - 800
  endif
  if ((nc1 >= 1) .and. (nc1 <= 62)) then
    iorg1 = 0;  ispa1 = 0;  ispb1 = 0
    korg1 = (nc1-30)*360 - 180
    if (nc1 > 60) korg1 = 0
    if (nc1 == 61) iorg1 = +5400
    if (nc1 == 62) iorg1 = -5400
  endif
  read(21,'(a)') buf
  read(buf,*) ixl1, iyl1, mszx1, mszy1, mxm1, mym1, anul, dmy, klp
  if ((area1 /= area) .or. (ncc1 /= ncc) .or. (iorg1 /= iorg)   &
      .or. (korg1 /= korg) .or. (ispa1 /= ispa) .or. (ispb1 /= ispb))   &
    call abendm('ADEQS Header inconsistent')
  if ((ixl1 /= ixlm) .or. (iyl1 /= iylm) .or. (mszx1 /= mszx)   &
      .or. (mszy1 /= mszy) .or. (mxm1 /= mxm) .or. (mym1 /= mym))   &
    call abendm('ADEQS Header inconsistent')
  read(21,*) ((s(i,j),i=1,mxm),j=1,mym)
  do
    read(21,'(a)') buf
    if (buf(1:1) /= '#') exit
  enddo
  if (buf(13:16) == '    ') then        !-- v2005
    read(buf,'(a8,i4,4x,4i8)') area1, ncc1, iorg1,korg1, ispa1,ispb1
    if ((ncc1<0) .or. (ncc1>=400)) call abendm('invalid coord.no.')
    nc1 = ncc1
    if (ncc1 < 200) then
      nc1 = ncc1; ncc1 = nc1 + 800
    else
      ncc1 = ncc1 - 200; nc1 = ncc1
    endif
  else                                  !-- v2018
    read(buf,'(a8,4x,i4,4i8)') area1, ncc1, iorg1,korg1, ispa1,ispb1
    nc1 = ncc1
    if ((ncc1 >= 800) .and. (ncc1 < 1000)) nc1 = ncc1 - 800
  endif
  if ((nc1 >= 1) .and. (nc1 <= 62)) then
    iorg1 = 0;  ispa1 = 0;  ispb1 = 0
    korg1 = (nc1-30)*360 - 180
    if (nc1 > 60) korg1 = 0
    if (nc1 == 61) iorg1 = +5400
    if (nc1 == 62) iorg1 = -5400
  endif
  read(21,'(a)') buf
  read(buf,*) ixl1, iyl1, mszx1, mszy1, mxm1, mym1, tnul
  if ((area1 /= area) .or. (ncc1 /= ncc) .or. (iorg1 /= iorg)   &
      .or. (korg1 /= korg) .or. (ispa1 /= ispa) .or. (ispb1 /= ispb))   &
    call abendm('ADEQ Header inconsistent')
  if ((ixl1 /= ixlm) .or. (iyl1 /= iylm) .or. (mszx1 /= mszx)   &
      .or. (mszy1 /= mszy) .or. (mxm1 /= mxm) .or. (mym1 /= mym))   &
    call abendm('ADEQ Header inconsistent')
  read(21,*) ((t(i,j),i=1,mxm),j=1,mym)
  read(21,'(2x,4f8.1)') dip, dec, the, phi
  rewind(21)
  hwm = hw * 1000.
  if ((nint(hwm/float(mszx)) /= nhx) .or.   &
      (nint(hwm/float(mszy)) /= nhy)) call abendm('ADEQS file broken')

  call premsg('Threshold percentage to regard converged')
  call gparmf('   (cont. 5 loops) [default: 2%] ==> ', thrsh)
  if ((thrsh < 0.) .or. (thrsh >= 20.)) call abendm('invalid parameter')
  if (thrsh == 0.) thrsh = 2.
  call gparmi('Maximum Loop Count [default: 100] ==> ', nloop)
  if (nloop <= 0) nloop = 100
  call clspin()
  call strdtm(sdtm)

  call dpcini('... read CFUPS matrix (0) : ')
  kc = 0
  do
    read(20,iostat=IER) k, ic, jc, (g(i),i=1,nnfw)
    if (IER < 0) exit
    kc = kc + 1
    if (k /= kc) call abendm('CFUPS file broken')
    call dpcent(kc, ndpt)
  enddo
  rewind(20)
  if (kc /= ndpt) call abendm('CFUPS file broken')

  write(6,'(a)')   '----------------------------------------'
  write(6,'(a)')   'ADEQSC : <adeqs> inversion until converge'
  write(6,'(a,a)') ' StdLIN data infile     : ', fnam1(1:lrtrim(fnam1))
  write(6,'(a,a)') ' CFUPS matrix infile    : ', fnam2(1:lrtrim(fnam2))
  write(6,'(a,a)') ' ADEQS model i/o file   : ', fnam3(1:lrtrim(fnam3))
  write(6,'(a12,a8,6x,a6,i4,4x,4i8)')   &
    'Areaname :  ', area, 'Coord.', ncc, iorg, korg, ispa, ispb
  write(6,'(4x,a)')   &
    '  (mesh)          xs        ys     msz-x   msz-y    mx    my    alt '
  write(6,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
    'reduc. surf.', xl,yl, mszx,mszy, mx,my, '    --- '
  write(6,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
    'eq.src.anom.', xlm,ylm, mszx,mszy, mxm,mym, '    var.'
  write(6,'(a,f6.2,a,i4,a,i4,a)')   &
    ' Half width of calc.window :', hw, ' km (', nhx, ' *', nhy, '  mesh )'
  write(6,'(a,f8.1,a)')   &
    ' Equiv. source anom. :', vd, ' m below Reduction alt.'
  write(6,'(a,f4.1,a)') ' Threshold to regard converged : ', thrsh, ' %'
  write(6,'(a,i4)') ' Max. Loop count :', nloop

  ss = 0.
  do j=1,mym; do i=1,mxm
    if (t(i,j) /= tnul) ss = ss + s(i,j)*s(i,j)
    p(i,j) = 0.
  enddo; enddo
  ds = sqrt(ss / float(mxm*mym))

  call conv1(g,nfx,nfy, s,mxm,mym, r,ndpt)
  ss = 0.
  do k=1,ndpt
    r(k) = f(k) - r(k)
    ss = ss + r(k)*r(k)
  enddo
  dv = sqrt(ss / float(ndpt))
  lp = 0
  write(6,'(a,i4,i3,a,f8.2,a,f7.2)')   &
    ' loop', klp, lp, '   rms.Step :', ds, '   rms.Residual :', dv
  open(9,status='scratch')
  write(9,*) klp, lp, ds, dv

  ilp = 0;  pvv = 1.
  do
    ilp = ilp + 1;  klp = klp + 1
    rv = dv;  pvvp = pvv
    call conv2(g,nfx,nfy, r,ndpt, v,mxm,mym)
    pvv = 0.
    do j=1,mym; do i=1,mxm;  pvv = pvv + v(i,j)*v(i,j);  enddo; enddo
    a = pvv / pvvp
    do j=1,mym; do i=1,mxm;  p(i,j) = v(i,j) + a*p(i,j);  enddo; enddo
    call conv1(g,nfx,nfy, p,mxm,mym, q,ndpt)
    pqq = 0.
    do k=1,ndpt;  pqq = pqq + q(k)*q(k);  enddo
    a = pvv / pqq;  ss = 0.
    do j=1,mym; do i=1,mxm
      s(i,j) = s(i,j) + a*p(i,j)
      if (t(i,j) /= tnul) ss = ss + p(i,j)*p(i,j)
    enddo; enddo
    ds = a * sqrt(ss / float(mxm*mym));  ss = 0.
    do k=1,ndpt;  r(k) = r(k) - a*q(k); ss = ss + r(k)*r(k);  enddo
    dv = sqrt(ss / float(ndpt))
    if (((rv-dv)/rv)*100.  >=  thrsh) then
      lp = 0
    else
      lp = lp + 1
    endif
    write(6,'(a,i4,i3,a,f8.2,a,f7.2)')   &
      ' loop', klp, lp, '   rms.Step :', ds, '   rms.Residual :', dv
    write(9,*) klp, lp, ds, dv
    if ((lp >= 5) .or. (dv < 0.1) .or. (ilp >= nloop)) exit
  enddo
  close(20)
  write(6,'(1x)')
  endfile(9)
  rewind(9)

  write(21,'(a8,4x,i4,4i8)') area, ncc, iorg,korg, ispa,ispb
  write(21,'(2i12,4i6,1x,f7.1,1x,f7.0,i6)')   &
    ixlm, iylm, mszx, mszy, mxm, mym, 9999.9, 0., klp
  do j=1,mym
    do i=1,mxm
      if (s(i,j) < -9999.8) s(i,j) = -9999.8
      if (s(i,j) > +9999.8) s(i,j) = +9999.8
    enddo
    write(21,'((f7.1,9(1x,f7.1)))') (s(i,j),i=1,mxm)
  enddo
  write(21,'(a8,4x,i4,4i8)') area, ncc, iorg,korg, ispa,ispb
  write(21,'(2i12,4i6,1x,f7.1,1x,f7.0)')   &
    ixlm, iylm, mszx, mszy, mxm, mym, tnul, -1.
  do j=1,mym
    write(21,'((f7.1,9(1x,f7.1)))') (t(i,j),i=1,mxm)
  enddo
  write(21,'(a2,4(1x,f7.1))') '# ', dip, dec, the, phi
  close(21)

  if (flog(ldr:ldr) /= ' ') then
    open(99,file=flog,access='append')
    write(99,'(//a)') 'ADEQSC : <adeqs> inversion until converge'
    write(99,'(a,a)') ' StdLIN data infile    : ', fnam1(1:lrtrim(fnam1))
    write(99,'(a,a)') ' CFUPS matrix infile   : ', fnam2(1:lrtrim(fnam2))
    write(99,'(a,a)') ' ADEQS model i/o file  : ', fnam3(1:lrtrim(fnam3))
    write(99,'(a,a,a)') '--------------- ', sdtm, '---------------'
    write(99,'(a12,a8,6x,a6,i4,4x,4i8)')   &
      'Areaname :  ', area, 'Coord.', ncc, iorg, korg, ispa, ispb
    write(99,'(4x,a)')   &
      '  (mesh)          xs        ys     msz-x   msz-y    mx    my    alt '
    write(99,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
      'reduc. surf.', xl,yl, mszx,mszy, mx,my, '    --- '
    write(99,'(4x,a12,2f10.2,2i8,2i6,a8)')   &
      'equiv.source', xlm,ylm, mszx,mszy, mxm,mym, '    var.'
    write(99,'(a,f6.2,a,i4,a,i4,a)')   &
      ' Half width of calc.window :', hw, ' km (', nhx, ' *', nhy, '  mesh )'
    write(99,'(a,f8.1,a)') ' Equiv.Source :', vd, ' m below Reduction alt.'
    write(99,'(a,f4.1,a)') ' Threshold to regard converged : ', thrsh, ' %'
    write(99,'(a,i4)') ' Max. Loop count :', nloop
    do
      read(9,*,iostat=IER) klp, lp, ds, dv
      if (IER < 0) exit
      write(99,'(a,i4,i3,a,f8.2,a,f7.2)')   &
        ' loop', klp, lp, '   rms.Step :', ds, '   rms.Residual :', dv
    enddo
    call strdtm(sdtm)
    write(99,'(a,a,a)') '=============== ', sdtm, '==============='
    close(99)
  endif
  close(9)
  stop
  end
!---
  subroutine conv1(g,nfx,nfy, s,mxm,mym, r,ndpt)
  implicit none
  integer,intent(in) :: nfx, nfy, mxm, mym, ndpt
  real,intent(inout) :: g(nfx,nfy)
  real,intent(in) :: s(mxm,mym)
  real,intent(out) :: r(ndpt)
  character(8) :: area
  integer :: nhx, nhy, i, j, k, np, ic, jc, kis, kjs, is, js
  real :: rp

  nhx = (nfx-1) / 2;  nhy = (nfy-1) / 2
  call dpcini('... read CFUPS matrix (1) : ')
  read(20) area, (i,k=1,16)
  do np=1,ndpt
    read(20) k, ic, jc, g
    rp = 0.;  kis = ic - nhx;  kjs = jc - nhy
    do j=1,nfy
      js = kjs + j;  if ((js <= 0) .or. (js > mym)) cycle
      do i=1,nfx
        is = kis + i;  if ((is <= 0) .or. (is > mxm)) cycle
        rp = rp + g(i,j)*s(is,js)
      enddo
    enddo
    r(np) = rp
    call dpcent(np, ndpt)
  enddo
  rewind(20)
  return
  end subroutine
!---
  subroutine conv2(g,nfx,nfy, r,ndpt, s,mxm,mym)
  implicit none
  integer,intent(in) :: nfx, nfy, ndpt, mxm, mym
  real,intent(inout) :: g(nfx,nfy)
  real,intent(in) :: r(ndpt)
  real,intent(out) :: s(mxm,mym)
  character(8) :: area
  integer :: nhx, nhy, i, j, k, is, js, np, ic, jc, kis, kjs
  real :: ss

  nhx = (nfx-1) / 2;  nhy = (nfy-1) / 2
  call dpcini('... read CFUPS matrix (2) : ')
  read(20) area, (i,k=1,16)
  do js=1,mym; do is=1,mxm;  s(is,js) = 0.;  enddo; enddo
  do np=1,ndpt
    read(20) k, ic, jc, g
    kis = ic - nhx;  kjs = jc - nhy;  ss = 0.
    do j=1,nfy
      js = kjs + j;  if ((js <= 0) .or. (js > mym)) cycle
      do i=1,nfx
        is = kis + i;  if ((is <= 0) .or. (is > mxm)) cycle
        s(is,js) = s(is,js) + g(i,j)*r(np)
      enddo
    enddo
    call dpcent(np, ndpt)
  enddo
  rewind(20)
  return
  end subroutine